FC2ブログ
01-<< 12345678910111213141516171819202122232425262728>>03-

APEXで1回きりのOutlet実行、自動OFF

2018-02-27
APEXで1回きりのOutlet実行、自動OFF

APEXを使っていて、例えば「水換えを今すぐ開始したい」、「自動給餌を今すぐ行いたい」って時が結構あります。それらのトリガー用Virtual Outletを用意してあったとしても、あとで手動でOFFにする必要がありますがそれを改善したいと思います。Google Homeのトリガーもこれを使っています

まぁ1年前ぐらいにやってあったのですが、紹介し忘れていましたので書いておきます

なお元の記事はこんな感じです。プログラムを比べてみてください
APEXを使った自動水換えシステム!
Automatic Feeding System


■ポイント
手動でOFFが不要になるポイントはWhen命令です。この命令は指定した時間(ここでは240分…4時間)経過したら強制的にOutletがOFFとなります
-----V_WTCHnow-----
Fallback OFF
Set ON
When On > 240:00 Then OFF


本来は自動給水でセンサー故障により給水しすぎたとき、自動停止させるために使います。その応用ですね。去年のファームウェア更新で実装されています
なお強制停止したあとはエラーとして記録されますので、E-mail送信やアラーム鳴らすってことができます
If Error V_WTCHnow Then ON

■自動水換えの開始トリガー
とりあえず実装した結果はこんな感じです
20180227_020.jpg

まずは自動水換えを手動でスタートさせるトリガーとなるのはこちらです。4時間経過したら止まります
-----水換え手動開始 V_WTCHnow-----
Fallback OFF
Set ON
When On > 240:00 Then OFF


これに伴って、それぞれ書き換えたので再掲しておきます

自動水換えをスケジュール起動させるトリガーです。スケジュールで水換えしない場合はOFFにしておきます。この設定では土曜日の12時から開始されます
-----水換えスケジュール開始 V_ATWTCh-----
Fallback OFF
Set OFF
If Time 12:00 to 16:00 Then ON
If DoW SMTWTF- Then OFF


そしてこれが水換えトリガーです。V_WTCHnowとV_ATWTChの両方どちらかがONなら水換えを開始するようにします
-----水換えトリガー V_WTCHtgr-----
Fallback OFF
Set OFF
If Output V_ATWTCh = ON Then ON
If Output V_WTCHnow = ON Then ON

If Output V_FeedTime = ON Then OFF
If FeedA 000 Then OFF
If FeedC 000 Then OFF
If FeedD 000 Then OFF


あと、以前はV_ATWTChが水換えトリガーだったので、それぞれV_WTCHtgrに書き換えます
-----みずためから給水ポンプ2 WT_PumpAT-----
Fallback OFF
If Output V_WTCHtgr = ON Then ON
If Output V_WTCHtgr = OFF Then OFF

If Output V_FltUpper = OFF Then OFF
If Output V_WTFlChk = ON Then OFF
If Output V_UpperChk = ON Then OFF
When On > 075:00 Then OFF
Defer 009:00 Then ON


排水については、給水と同時に行うようにしました。「If Output WT_PumpAT = ON Then OFF」を消しただけです。以前は給水して水位が上がってから排水していましたが、時間がかかるのでスピードアップのためです。どちらでも良いかと思います
-----排水ポンプ WT_DrPump-----
Fallback OFF
If Output V_WTCHtgr = ON Then ON
If Output V_WTCHtgr = OFF Then OFF

If Output V_FltLower = OFF Then OFF
When On > 080:00 Then OFF
Defer 003:05 Then ON


これは変えていませんが再掲
-----サンプの上フロートスイッチ検知 V_FltUpper-----
Fallback OFF
Set OFF
If S_UpF1 OPEN Then ON
If S_UpF2 CLOSED Then OFF
Defer 000:05 Then ON


これも再掲
-----サンプの下フロートスイッチ検知 V_FltLower-----
Fallback OFF
Set OFF
If S_DwF1 OPEN Then ON
If S_DwF2 CLOSED Then OFF
Defer 000:05 Then OFF


-----給水の流量チェック V_WTFlChk-----
Fallback OFF
If Output WT_PumpAT = ON Then ON
If Output V_WTCHtgr = OFF Then OFF
If FlowWT > 10.0 Then OFF
Defer 000:20 Then ON
Min Time 060:00 Then ON


給水も排水もしていない時は、プロテインスキマーをONにするように修正しました
-----スキマーOFF V_SkimStop-----
Fallback OFF
Set OFF
If Output WT_PumpAT = ON Then ON
If Output V_WTCHtgr = ON Then ON
If Output V_SkimStart = OFF Then ON
If Output V_SkimStart = ON Then OFF


これは前無かったと思います。給水も排水もしていない時は、プロテインスキマーをONにします。水換えが早めに終わったらスキマーを自動再開させるためです
-----スキマーON V_SkimStart-----
Fallback OFF
Set ON
If Output WT_DrPump = ON Then OFF
If Output WT_PumpAT = ON Then OFF
Defer 010:00 Then ON


こちらはそのまま(自動給餌の設定が追加にはなっていますが)
-----スキマー Skimmer-----
Fallback ON
Set ON
If Output V_FeedDL60M = ON Then OFF
If Output V_SkimStop = ON Then OFF
If FeedA 060 Then OFF
If FeedC 003 Then OFF
If FeedD 003 Then OFF


-----自動給水 V_ROtime-----
Fallback OFF
Set OFF
If Time 23:00 to 23:03 Then ON
If Time 05:00 to 05:03 Then ON
If Time 11:00 to 11:03 Then ON
If Time 17:00 to 17:03 Then ON
If Output V_WTCHtgr = ON Then OFF


■自動給餌の開始トリガー
実装した結果はこんな感じです
20180227_020.jpg

構造は同じですね

こちらがフィードモードを手動で開始するトリガーです。20分で停止します
-----自動給餌の手動開始 V_Feednow-----
Fallback OFF
Set ON
When On > 020:00 Then OFF


こちらがスケジュールで起動する場合です。AFSで給餌するだけなので、15分で再開です
-----自動給餌のスケジュール開始 V_FeedAuto-----
Fallback OFF
Set OFF
If Time 07:00 to 07:15 Then ON
If FeedA 000 Then OFF
If FeedC 000 Then OFF
If FeedD 000 Then OFF


上記のV_FeednowとV_FeedAutoを統合して、どちらかONなら開始します
-----自動給餌のトリガー V_FeedTime-----
Fallback OFF
Set OFF
If Output V_FeedAuto = ON Then ON
If Output V_Feednow = ON Then ON

If FeedA 000 Then OFF
If FeedC 000 Then OFF
If FeedD 000 Then OFF


復帰後の待ち時間用はこちらです。これは2分待ち
-----2分待ち V_FeedDL2M-----
Fallback OFF
Set OFF
If Output V_FeedTime = ON Then ON
Defer 000:05 Then ON
If Output V_FeedTime = OFF Then OFF
Defer 002:00 Then OFF


同じく10分待ち。メール送信を止めるために使います
-----10分待ち V_FeedDL10M-----
Fallback OFF
Set OFF
If Output V_FeedTime = ON Then ON
Defer 000:05 Then ON
If Output V_FeedTime = OFF Then OFF
Defer 010:00 Then OFF


同じく60分待ち。スキマー停止に使います
-----60分待ち V_FeedDL60M-----
Fallback OFF
Set OFF
If Output V_FeedTime = ON Then ON
If Output V_FeedTime = OFF Then OFF
Defer 060:00 Then OFF


AFSそのものは変更ありません
-----AFS Feeder-----
Fallback OFF
Set OFF
If Output V_FeedTime = ON Then ON
If FeedA 000 Then ON
If FeedB 000 Then OFF
If FeedC 000 Then OFF
If FeedD 000 Then OFF
Defer 003:00 Then ON


FeedAが定義されている各機材に対して、この待ち用Outletを定義します。例えばこんな感じ
-----ROの電磁弁 ROSValve-----
Fallback OFF
Set ON
If Output V_FltUpper = OFF Then OFF
If Output V_FltLower2 = OFF Then OFF
If Output V_ROtime = OFF Then OFF
If Output V_FeedTime = ON Then OFF
When On > 004:00 Then OFF
Defer 000:05 Then ON
Defer 000:05 Then OFF
If FeedA 000 Then OFF
If FeedC 000 Then OFF
If FeedD 000 Then OFF


2分待ちさせたい機材は定義するOutletを変えればOKです
-----メインポンプ MainPump-----
Fallback ON
Set ON
If Output V_FeedDL2M = ON Then OFF
If FMM_Lk CLOSED Then OFF
Defer 000:10 Then ON
Defer 000:10 Then OFF
If FeedA 001 Then OFF
If FeedC 001 Then OFF
If FeedD 001 Then OFF


スキマーは60分待ちです
-----スキマー Skimmer-----
Fallback ON
Set ON
If Output V_FeedDL60M = ON Then OFF
If Output V_SkimStop = ON Then OFF
If FeedA 060 Then OFF
If FeedC 003 Then OFF
If FeedD 003 Then OFF


といった感じです。ちょっと長いですがこんな感じでできます

スポンサーサイト





B!
関連記事
★Neptune Apex★ | コメント:(0) | トラックバック:(0)
 | ホーム | 

FC2 Blog Ranking Related Posts Plugin for WordPress, Blogger...